使用 CellRenderer API

// ActionScript 2.0 class.
class MultiLineCell extends mx.core.UIComponent
{
    private var multiLineLabel; // 用于显示文本的标签。
    private var owner; // 包含此单元格的行。
    private var listOwner; // 包含此单元格的列表、数据网格或树。

    // 单元格高度相对于行总高度的偏移量以及首选的单元格宽度。
    private static var PREFERRED_HEIGHT_OFFSET = 4; 
    private static var PREFERRED_WIDTH = 100;
    // 起始深度。
    private var startDepth:Number = 1;

    // 构造函数。应为空。
    public function MultiLineCell()
    {
    }

    /* UIObject 期望您通过实例化初始化期间可能需要的所有影片剪辑资源来填充 createChildren。在本例中，我们创建的是一个标签*/
    public function createChildren():Void
    {
        // createLabel 方法是 UIObject 的一种很有用的方法，并且是一种
        // 在组件中创建标签的便利方法。
        var c = multiLineLabel = this.createLabel("multiLineLabel", startDepth);
        // 将该标签的样式链接到网格的样式
        c.styleName = listOwner;
        c.selectable = false;
        c.tabEnabled = false;
        c.background = false;
        c.border = false;
        c.multiline = true;
        c.wordWrap = true;
    }

    public function size():Void
    {
/* 通过扩展用于导入 UIObject 的 UIComponent，将自动获取 setSize，但 UIComponent 期望您实现 size()。假设现在为您设置了 __width 和 __height。您将要扩展单元格以适应整个 rowHeight。rowHeight 本身是要在其中呈现单元格的列表类型组件的属性。由于我们需要 rowHeight 适合两行的高度，因此在使用此 cellRenderer 类创建该列表类型组件时，请确保将其 rowHeight 属性设置为足够大，以便在该组件中可以呈现两行文本。*/
    
/*__width 和 __height 是 getter/setter  .width 和 .height 的基础变量。*/
        var c = multiLineLabel;
        c.setSize(__width, __height);
    }

    // 提供单元格的首选高度。继承的方法。
    public function getPreferredHeight():Number
    {
/* 为单元格赋予一个引用行的属性"owner"。首选的做法总是让单元格占用行的大部分高度。在本例中，我们将使单元格略小一些。*/
        return owner.__height - PREFERRED_HEIGHT_OFFSET;
    }

    // 由 owner 调用以设置单元格中的值。继承的方法。
    public function setValue(suggestedValue:String, item:Object, selected:Boolean):Void
    {
/* 如果未定义 item 参数，则不应在单元格中呈现任何内容，因此将标签设置为不可见。注意：对于滚动列表类型组件（如滚动数据网格），在单元格刚滚动出视线之外时就使其为空，然后再次重用该单元格，并为其设置产生滚动动画效果的新值。出于此原因，您不能指望任一单元格始终包含要显示的数据或包含同一值。*/
        if (item!=undefined){
            multiLineLabel.text._visible = false;
        }
        multiLineLabel.text = suggestedValue;
    }
    // 函数 getPreferredWidth ::仅用于菜单和数据网格标题
    // 函数 getCellIndex ::在此单元格渲染器中不使用
    // 函数 getDataLabel ::在此单元格渲染器中不使用
}

// 创建一个新的 DataGrid 组件实例
this.createClassObject(mx.controls.DataGrid, "myGrid_dg", 1);

// 为包含四列数据的数据网格构建一个数据提供程序。
myDP = new Array();
var aLongString:String = "An example of a cell renderer class that displays a multiple line TextField";
myDP.addItem({firstName:"Winston", lastName:"Elstad", note:aLongString, item:100});
myDP.addItem({firstName:"Ric", lastName:"Dietrich", note:aLongString, item:101});   
myDP.addItem({firstName:"Ewing", lastName:"Canepa", note:aLongString, item:102});   
myDP.addItem({firstName:"Kevin", lastName:"Wade", note:aLongString, item:103});   
myDP.addItem({firstName:"Kimberly", lastName:"Dietrich", note:aLongString, item:104});   
myDP.addItem({firstName:"AJ", lastName:"Bilow", note:aLongString, item:105});   
myDP.addItem({firstName:"Chuck", lastName:"Yushan", note:aLongString, item:106});
myDP.addItem({firstName:"John", lastName:"Roo", note:aLongString, item:107});

/* 将该数据提供程序分配到 DataGrid 以填充该网格。注意：必须在应用 cellRenderer 之前执行此操作。*/
myGrid_dg.dataProvider = myDP;

/* 设置某些基本的网格属性。注意：该数据网格的行高应反映您期望在 MultiLineCell 单元格渲染器中显示的行数。单元格渲染器将调整为该行高度。对于默认文本大小，该行高度大约是两行文本的行高 40 或三行文本的行高 60。*/
myGrid_dg.setSize(430,200);
myGrid_dg.move(40,40);
myGrid_dg.rowHeight = 40; // 对于默认文本大小，使用两行文本的行高。
myGrid_dg.getColumnAt(0).width = 70;
myGrid_dg.getColumnAt(1).width = 70;
myGrid_dg.getColumnAt(2).width = 220;
myGrid_dg.resizableColumns = true;
myGrid_dg.vScrollPolicy = "auto";
myGrid_dg.setStyle("backgroundColor", 0xD5D5FF); 

// 分配 cellRenderer。
myGrid_dg.getColumnAt(2).cellRenderer = "MultiLineCell";